Conjuntos de productos en Google Sheets
Para crear un conjunto de productos en Feedom es necesario contar con un documento de Google Sheet en donde se carguen los productos que formarán parte del conjunto.
Para poder armar los conjuntos, podemos pegar en una pestaña del sheet un listado de IDs de los productos o bien, tomar como base el feed de productos de Feedom y todos los datos que contiene.
! Atención: si se utiliza un listado de IDs de los productos, es importante chequear que sean los mismos ID que los que figuran en feedom. Esto puedes hacerlo revisando la pestaña productos dentro de la app, chequeando el campo ID.
En este instructivo, te ayudaremos a crear un conjunto de productos utilizando como base el feed de Feedom.
Paso 1
Pídele a tu ejecutivo de cuentas que te comparta la URL de tu feed de productos.
Para poder utilizar el feed en el sheet, inserta la URL en la siguiente fórmula:
=IMPORTDATA(“url-de-tu-feed”)
👉🏼 Esto hará que tengas en el sheet la información de tus productos, actualizada automáticamente cada una hora. Ahora podrás utilizarlo de fuente para crear conjuntos de productos.
Paso 2
Una vez que tengas la pestaña con la información del feed, ya puedes empezar a crear hojas dentro del sheets para tus distintos conjuntos de productos.
Aquí te dejamos un documento en donde cada pestaña tiene aplicada una fórmula distinta. Puedes hacer una copia, importar tu feed (Paso 1) y aprovechar las fórmulas que ya están armadas.
Explicaremos cada una de estas fórmulas, que son las que creemos que más pueden servirte, pero tu puedes crear las fórmulas que creas necesarias y generar los conjuntos de productos que más te convengan.
Aclaración: las fórmulas que te acercaremos son para poder traer los IDs de los productos utilizando distintos filtros. Si quieres traer en otra columna los nombres de los productos, debes usar la siguiente fórmula:
=SI(LARGO(A2)=0;;INDICE(feed!B:B;COINCIDIR(A2;feed!A:A;0)))
Fórmulas para crear conjuntos de productos
1) Conjuntos de productos usando el campo product type del feed
El campo product type indica la categoría a la que pertenece el producto. Con esta información podemos generar conjuntos de productos para categorías específicas del sitio. En este ejemplo, vamos a utilizar la categoría “Perfumes & Fragancias > Mujer Importado”.
👉🏼 Fórmula filter
La fórmula filter permite setear filtros para traernos la data específica que necesitamos.
En este caso, utilizamos la información del feed y aplicamos el filtro para que la columna J (product_type) sea igual a la categoría que necesitamos, quedándonos la fórmula así:
=FILTER('Feed'!A:A;'Feed'!J:J="Perfumes & Fragancias > Mujer Importado")
Explicación de la fórmula
'Feed'!A:A
Esta es la columna donde tenemos los IDs de los productos.
'Feed'!J:J
Esta es la columna donde tenemos el product type (la categoría del producto)
= "Perfumes & Fragancias > Mujer Importado"
Este es el filtro que vamos a aplicarle a la lista de IDs. Escribimos el nombre de la categoría que nos queremos traer.
2) Conjuntos de productos usando el campo product title del feed
El campo title es el nombre del producto. Con esta información podemos generar un conjunto con productos que tengan un nombre específico.
👉🏼 Fórmula filter
En este ejemplo vamos a utilizar el texto "Jean" para hacer el filtro.
El filtro que aplicamos es para que nos traiga solamente los productos que en la columna B del feed (title) contengan el valor “Jean”. La fórmula quedaría así:
=FILTER('Feed'!A:A;REGEXMATCH('Feed'!B:B;"Jean"))
Explicación de la fórmula
'Feed'!A:A
Esta es la columna donde tenemos los IDs de los productos
REGEXMATCH('Feed'!B:B;"Jean")
Este es el filtro que vamos a aplicarle a la lista de IDs. La fórmula regexmatch permite usar una expresión regular para encontrar valores de texto dentro de una celda determinada, en este caso lo que estamos haciendo es buscar la palabra “Jean” dentro del nombre de los productos.
3) Conjuntos de productos usando el campo sale_price del feed
El campo sale_price es el valor del precio con descuento del producto. Con esta información podemos generar conjuntos de productos que estén dentro de un rango de precios específico. En este ejemplo vamos a buscar los productos que estén entre $10 y $40.
👉🏼 Fórmula filter
En este caso, el filtro que le pondremos es para que nos devuelva los productos cuyos valores de la columna S del feed (sale_price_modified) estén entre $10 y $40. La fórmula quedaría así:
=FILTER('Feed'!A:A;'Feed'!S:S>10;'Feed'!S:S<40)
Explicación de la fórmula
'Feed'!A:A
Esta es la columna donde tenemos los IDs de los productos
'Feed'!S:S>10
Acá indicamos que queremos que nos traiga todos los productos que tengan un valor de sale_price_modified mayor a $10
'Feed'!S:S<40
Este es el segundo filtro, se aplica como condición extra a la que ya habíamos seteado. Hace que se traigan todos los productos que tengan un valor de sale_price_modified menor a $40.
Ambas condiciones combinadas nos devuelven un listado de IDs, filtrado por productos que tengan un precio entre $10 y $40.
4) Conjuntos de productos usando el campo discount del feed
El campo discount es el porcentaje de descuento del producto. Con esta información podemos generar conjuntos con los productos que tengan descuento. En este ejemplo vamos a buscar los productos en los que el descuento sea mayor a 5%.
👉🏼 Fórmula filter
En este caso, el filtro que le ponemos es para que nos devuelva los productos cuyo valor de la columna O del feed (discount) es mayor a 5. La fórmula quedaría así:
=FILTER('Feed'!A2:A;'Feed'!O2:O>5)
Explicación de la fórmula
'Feed'!A:A
Esta es la columna donde tenemos los IDs de los productos.
'Feed'!O2:O>5
Acá indicamos que queremos que nos traiga todos los productos que tengan un valor de discount mayor a 5%.
5) Conjuntos de productos usando más de un campo del feed
En este caso, la idea es combinar dos condiciones para poder generar el conjunto de productos. La fórmula filter admite la cantidad de condiciones que necesites. En este ejemplo, seteamos las condiciones para que nos devuelva todos los productos en stock (condición 1), que tengan cuotas (condición 2).
Fórmula filter
En este caso, el filtro que aplicamos es para que nos devuelva los productos cuyo valor de la columna K del feed (availability) sea igual a “IN_STOCK” y que, además, cumpla con que el valor de la columna P del feed (installments) sea mayor a 1. La fórmula quedaría así
=FILTER('Feed'!A2:A;'Feed'!K2:K="IN_STOCK";'Feed'!P2:P>1)
Explicación de la fórmula
'Feed'!A:A
Esta es la columna donde tenemos los IDs de los productos.
'Feed'!K2:K="IN_STOCK"
Acá indicamos que queremos que nos traiga todos los productos que tengan un valor de availability igual a “in stock”.
'Feed'!P2:P>1
Este es el segundo filtro, se aplica como condición extra a la que ya habíamos seteado. Hace que se traigan todos los productos que tengan el valor de installments (cuotas) mayor a 1.
Ambas condiciones combinadas nos devuelven un listado de IDs filtrado por productos que estén en stock y que, además, tienen cuotas.